Ramblings: November 2012

"...separating logic from presentation" is good thing; and you don`t need much presentation before code can start looking a bit messy. Here is an example of mine at about the limit of what I feel comfortable with.

Landscape

I have been using Node.js a bit recently and it has an impressive list of templating engines. One of the things I like about Node is the module ecosystem; where vast numbers of different approaches compete in Darwinian fashion for "developer mind share". For reasons that I can't quite remember, I ended up using EJS with custom delimiters of single { and }. It looks a bit like XQuery.

When it comes to XQuery there are not so many choices :-). Maybe most are mentioned in this thread: eXist MVC and separating XHTML templates from XQuery code More recently eXistdb has Exist html templates. This looks to be standard XQuery 3.0 and provide a lot of high level functionality, but very much linked into the eXistdb environment.

What the world needs now is...

.. another XQuery templating system. So from my experience with EJS and express.js. Some features that I liked are:

A render method to take a view and a map type object to produce a page
A location, a collection or folder, for templates (views) completely separated from the code.
A quick syntax to wrap common page features around rendered results.
A block/partial/repeat type concept for list/tables.

Looking for the simplest thing that might possibly work..Noting that:

A XML document is a valid XQuery program.
If we put some {$var} type expressions in it and get XQuery to evaluate it in the right context- we are almost there.
BaseX has a (non-standard) function xquery:invoke that has just the right signature.

The start..

	declare function txq:render($template,$map){
	xquery:invoke($template,$map)
	}

view raw render.xq hosted with ❤ by GitHub

With this view1.xml template

<div>{$greeting} {$who}</div>

view raw view1.xml hosted with ❤ by GitHub

Invoking..

	txq:render("view1.xml",map{"greeting":="hello","who":="world"})

	(: result :)
	<div>hello world</div>

view raw simple.xq hosted with ❤ by GitHub

Layout pages use the convention that a layout template has a $body field into which the sub template will be inserted

	(:~
	: template function with wrapping layout
	: @param layout
	: @return updated doc from map
	:)
	declare function render($template as xs:string,$map as map(*),
	$layout as xs:string){
	let $content:=render($template,$map)
	let $map:=map:new(($map,map{"body":=$content}))
	return render($layout,$map)
	};

view raw render2.xq hosted with ❤ by GitHub

Example layout template.

	<html>
	<head><title>{$title}</title>
	<script src="...."></script>
	</head>
	<body>
	<div>..nav bar..</div>
	{$body}
	</body>
	</html>

view raw layout.xml hosted with ❤ by GitHub

Invoking

	let $map:=map{"greeting":="hello","who":="world","title":="full page"}
	return txq:render("view1.xml", $map, "layout.xml")

	(: result :)
	<html>
	<head><title>full page</title>
	<script src="...."></script>
	</head>
	<body>
	<div>..nav bar..</div>
	<div>hello world</div>
	</body>
	</html>

view raw page.xq hosted with ❤ by GitHub

Often there is a need to render repeated items from some node collection. A solution to this repeatedly invoke a sub-template, injecting a map with an item set to each node in turn. For example our map has a "actions" value. An XML node with a variable number of <generate> sub nodes that we wish to render.

	<div>
	<h2>{$heading} - {count($actions/generate)}</h2>
	<p>Actions are processes that generate a new item from an existing item.</p>
	<div>
	{$partial("action1.xml","action",$actions/generate )}
	</div>
	</div>

view raw actions.xml hosted with ❤ by GitHub

The actions1.xml partial template.

	<div>
	<h3>{$action/@id/string()}</h3>
	<span class="label">{$action/@in/string()}</span> → <span class="label">{$action/@out/string()}</span>
	<p>{$action/describe}</p>
	<pre>{$action/xquery}</pre>
	</div>

view raw actions1.xml hosted with ❤ by GitHub

A slight addition to the original render function makes this easy. Below shows the the full TXQ module.

	(:~
	: A(nother) templating Engine for XQuery (BaseX 7.5 specific)
	: specials:
	: partial(file,name,sequence)
	:
	: @author andy bunce
	: @since sept 2012
	:)

	module namespace txq = 'apb.txq';
	declare default function namespace 'apb.txq';
	import module namespace xquery = "http://basex.org/modules/xquery";

	(:~
	: template function
	: @param template url to fill
	: @param map name and value to apply
	: @return updated doc from map
	:)
	declare function render($template as xs:string,$map as map(*)){
	let $map:=map:new(($map,map{"partial":=partial(?,?,?,$map,$template)}))
	return xquery:invoke($template,$map)
	};

	(:~
	: template function with wrapping layout
	: @param layout
	: @return updated doc from map
	:)
	declare function render($template as xs:string,$map as map(*),$layout as xs:string){
	let $content:=render($template,$map)
	let $map:=map:new(($map,map{"body":=$content}))
	return render($layout,$map)
	};



	(:~
	: partial template function: evaluate part for each value in sequence
	: @return updated doc from map
	:)
	declare function partial($part as xs:string,$name,$seq,$map,$base){
	for $s in $seq
	let $map:=map:new(($map,map{$name:=$s}))
	return render(fn:resolve-uri($part,$base),$map)
	};

view raw txq.xqm hosted with ❤ by GitHub

Ramblings

Monday, 19 November 2012

XQuery templating engines and TXQ

Landscape

What the world needs now is...

Saturday, 10 November 2012

Software updates

NAS updates

PaaS